@Echo Off
cls


REM   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
REM   CHOOSE WHICH BIOS VERSION YOU WANT BY UNCOMMENTING (REMOVE
REM   THE "REM") THE VERSION YOU WANT.
REM   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

REM GE10208  = LATEST PIC WINDOWS CE LOCKED BIOS FOR REGULAR PIC IMAGE
REM XPWITHCD = UNLOCKED PIC BIOS TO SUPPORT WINDOWS/LINUX OS WITH CD BOOT SUPPORT
REM XPNOCD   = UNLOCKED PIC BIOS TO SUPPORT WINDOWS/LINUX OS WITH NO CD BOOT SUPPORT (FASTER BOOT)
REM CEWITHCD = UNLOCKED PIC BIOS TO SUPPORT WINDOWS CE WITH CD BOOT SUPPORT
REM CENOCD   = UNLOCKED PIC BIOS TO SUPPORT WINDOWS CE WITH NO CD BOOT SUPPORT (FASTER BOOT)

REM set BIOSVER=GE10208  
REM set BIOSVER=XPWITHCD
REM set BIOSVER=XPNOCD
REM set BIOSVER=CEWITHCD
REM set BIOSVER=CENOCD

:BEGIN
cls
Echo =====================================================================
Echo                    EDYNAMO BIOS FLASHING TOOL
Echo =====================================================================
Echo.
Echo +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Echo                Choose the BIOS version to install
Echo                 or exit to the DOS command line
Echo +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Echo 1 Original locked WinCE BIOS
Echo 2 Unlocked BIOS for WinXP or Linux with CD support
Echo 3 Unlocked BIOS for WinXP or Linux without CD support (faster boot)
Echo 4 Unlocked BIOS for WinCE with CD support
Echo 5 Unlocked BIOS for WinCE without CD support (faster boot)
Echo 6 Exit to FreeDOS command prompt
CHOICE /C:123456
IF ErrorLevel 6 goto EXIT_TO_PROMPT
IF ErrorLevel 5 goto CENOCD
IF ErrorLevel 4 goto CEWITHCD
IF ErrorLevel 3 goto XPNOCD
IF ErrorLevel 2 goto XPWITHCD
IF ErrorLevel 1 goto GE10208

:GE10208
set BIOSVER=GE10208
goto FLASH_ROM
:XPWITHCD
set BIOSVER=XPWITHCD
goto FLASH_ROM
:XPNOCD
set BIOSVER=XPNOCD
goto FLASH_ROM
:CEWITHCD
set BIOSVER=CEWITHCD
goto FLASH_ROM
:CENOCD
set BIOSVER=CENOCD
goto FLASH_ROM

:FLASH_ROM
flashrom /j
IF ErrorLevel 65 goto TOO_BIG
IF ErrorLevel 64 goto ROM_4MEG
IF ErrorLevel 32 goto ROM_2MEG
IF ErrorLevel 16 goto ROM_1MEG
IF ErrorLevel 8 goto ROM_512k
IF ErrorLevel 4 goto ROM_256k
goto ERROR
:ERROR
   echo.
	echo Unable to identIFy ROM size!
   echo.
	goto FLASHEXIT
:TOO_BIG
:ROM_1MEG
:ROM_2MEG
:ROM_4MEG
   echo.
	echo What are you trying to flash?  It aint no PIC or decTOP!
   echo.
	goto END
:ROM_256k
   echo.
	echo Flashing a 256k BIOS...
   echo.
   flashrom %BIOSVER%.256 /sFFFC0000
   flashrom /c
	goto FLASHEXIT
:ROM_512k
   echo.
	echo Flashing a 512k BIOS...
   echo.
   flashrom %BIOSVER%.512 /sFFF80000
   flashrom /c
	goto FLASHEXIT
:FLASHEXIT
Echo +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Echo      Would you like to format and repartition the hard drive?
Echo     Warning! Doing so will destroy all data on the hard drive!
Echo.
CHOICE
if errorlevel 2 goto EXIT_NO_FORMAT

Echo Please Wait While The Primary Disk Is Cleaned.......
gdisk 2 /DEL /ALL /Y
disksz.exe
if ErrorLevel 37 goto GB40Drive
if ErrorLevel 19 goto GB20Drive
if ErrorLevel 10 goto GB10Drive
if ErrorLevel 3 goto GB3Drive
echo Error... don't recognize the drive size!
goto END

:GB3Drive
Echo Partitioning a 3 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:2828 /V:System /Y
goto FinishPart

:GB10Drive
Echo Partitioning a 10 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:9748 /V:System /Y
goto FinishPart

:GB20Drive
Echo Partitioning a 20 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:19068 /V:System /Y
goto FinishPart

:GB40Drive
Echo Partitioning a 40 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:38128 /V:System /Y
goto FinishPart

:FinishPart
gdisk 2 /ACT /P:1
:EXIT_NO_FORMAT
echo Finished flashing BIOS
goto END
:EXIT_TO_PROMPT
Echo You can re-run the BIOS utility with the command 'autoexec'
Echo Exiting to FreeDOS command prompt
:End