@Echo Off
cls


REM   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
REM   CHOOSE WHICH BIOS VERSION YOU WANT BY UNCOMMENTING (REMOVE
REM   THE "REM") THE VERSION YOU WANT.
REM   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

REM GE10208  = LATEST PIC WINDOWS CE LOCKED BIOS FOR REGULAR PIC IMAGE
REM XPWITHCD = UNLOCKED PIC BIOS TO SUPPORT WINDOWS/LINUX OS WITH CD BOOT SUPPORT
REM XPNOCD   = UNLOCKED PIC BIOS TO SUPPORT WINDOWS/LINUX OS WITH NO CD BOOT SUPPORT (FASTER BOOT)
REM CEWITHCD = UNLOCKED PIC BIOS TO SUPPORT WINDOWS CE WITH CD BOOT SUPPORT
REM CENOCD   = UNLOCKED PIC BIOS TO SUPPORT WINDOWS CE WITH NO CD BOOT SUPPORT (FASTER BOOT)

REM set BIOSVER=GE10208  
set BIOSVER=XPWITHCD
REM set BIOSVER=XPNOCD
REM set BIOSVER=CEWITHCD
REM set BIOSVER=CENOCD

:BEGIN
cls
Echo =====================================================================
Echo               EDYNAMO BIOS FLASHING TOOL
Echo =====================================================================
Echo.
flashrom /j
IF ErrorLevel 65 goto TOO_BIG
IF ErrorLevel 64 goto ROM_4MEG
IF ErrorLevel 32 goto ROM_2MEG
IF ErrorLevel 16 goto ROM_1MEG
IF ErrorLevel 8 goto ROM_512k
IF ErrorLevel 4 goto ROM_256k
goto ERROR
:ERROR
   echo.
	echo Unable to identIFy ROM size!
   echo.
	goto FLASHEXIT
:TOO_BIG
:ROM_1MEG
:ROM_2MEG
:ROM_4MEG
   echo.
	echo What are you trying to flash?  It aint no PIC!
   echo.
	goto END
:ROM_256k
   echo.
	echo Flashing a 256k BIOS...
   echo.
   flashrom %BIOSVER%.256 /sFFFC0000
   flashrom /c
	goto FLASHEXIT
:ROM_512k
   echo.
	echo Flashing a 512k BIOS...
   echo.
   flashrom %BIOSVER%.512 /sFFF80000
   flashrom /c
	goto FLASHEXIT
:FLASHEXIT
Echo Please Wait While The Primary Disk Is Cleaned.......
gdisk 2 /DEL /ALL /Y
disksz.exe
if ErrorLevel 37 goto GB40Drive
if ErrorLevel 19 goto GB20Drive
if ErrorLevel 10 goto GB10Drive
if ErrorLevel 3 goto GB3Drive
echo Error... don't recognize the drive size!
goto END

:GB3Drive
Echo Partitioning a 3 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:2828 /V:System /Y
goto FinishPart

:GB10Drive
Echo Partitioning a 10 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:9748 /V:System /Y
goto FinishPart

:GB20Drive
Echo Partitioning a 20 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:19068 /V:System /Y
goto FinishPart

:GB40Drive
Echo Partitioning a 40 GB drive...
gdisk 2 /CRE /PRI /FOR /Q /SZ:38128 /V:System /Y
goto FinishPart

:FinishPart
gdisk 2 /ACT /P:1

:End