echo off
echo Constructing Kermit-CC for IBM-PCs.
echo Please use option "/DCGA" if you want to make a Kermit version running
echo on CGA or MDA machines.
Break on
Rem  Assumes all files are on the current disk.
Rem  If there is insufficient disk space then the command
Rem  "masm filespec.asm;"
Rem  may be typed individually for each .asm file.
Rem  Note: files CCSDEF.H and CCVIBM.LNK must be in the current directory for
Rem  use by masm and link, respectively.

Rem  First, the system independent .asm files: ccscmd, ccscom, ccsfil, ccsker,
Rem  ccsrcv, ccsscp, ccssen, ccsser, ccsset, ccster, ccsfin
if not exist ccsdef.h goto noheader
echo Make an .OBJ file from each .ASM file.
for %%f in (ccscmd, ccscom, ccsfil, ccsker, ccsrcv, ccsscp) do masm %%f;
for %%f in (ccssen, ccsser, ccsset, ccster, ccsfin) do masm %%f;

Rem Second, the system dependent files: ccgibm, ccuibm, ccxibm, ccyibm, cczibm
Rem  cchkos
for %%f in (ccgibm, ccuibm, ccxibm, cczibm, cchkos) do masm %%f;
masm %1 ccyibm;
echo End of Assembly step.

Rem  Third, link the Object files, using the appropriate command file.
echo Starting Link step.
link @ccvibm.lnk
if errorlevel 1 goto badlink
echo File CCVIBM.EXE is built.
Rem  Display version number.
ccvibm -f nul, exit
goto done
:noheader
echo ERROR - File CCSDEF.H is needed but could not be found.
goto done
:badlink
echo LINKING ERROR.
:done
echo on