.title	krter4	overlay 4 of 4 for misc error text
	.ident	/V04.64/

; /E64/	10-May-96  John Santos
;
;	New module with RSTS/E-Kermit-specific error messages, roughly
;	corresponding to KRTERR.MAC
;	Returns error text for fake RSTS/E errors with error codes
;	greater than 256., which are kermit internal error messages.

	.include "IN:KRTMAC.MAC"
	.iif ndf  KRTINC  .error	<; .include for IN:KRTMAC.MAC failed>

	.include	/SY:[1,2]COMMON.MAC/
	.iif ndf, xrb   , .error ; INCULDE for [1,2]COMMON.MAC failed

	.title	krter4

	.psect	$pdata
	.sbttl	Error codes defined


	er$lgf	==	256.+1.		; please open a logfile first
	er$raw	==	256.+2.		; can't log raw I/O with other opts
	er$rax	==	256.+3.		; can't do this with raw logging
	er$mal	==	256.+4.		; malloc can't get enough memory
	er$spe	==	256.+5.		; unknown speed
	er$bnl	==	256.+6.		; binary types list is full
	er$one	==	256.+7.		; illegal file type
	er$try	==	256.+8.		; retries must be 3 to 30 only
	er$tim	==	256.+9.		; set time_out error
	er$txp	==	256.+10.	; /62/ packet min len is 20 bytes
	er$bad	==	256.+11.	; bad option or value
	er$sam	==	256.+12.	; ambiguous set command
	er$sun	==	256.+13.	; unrecognizable set command
	er$tt	==	256.+14.	; can't connect TT to TT
	er$ass	==	256.+15.	; assign error
	er$get	==	256.+16.	; get syntax error
	er$tam	==	256.+17.	; ambiguous topic
	er$tun	==	256.+18.	; unrecognizable topic
	er$ser	==	256.+19.	; no server subcommands
	er$dcd	==	256.+20.	; can't dial whilst DCD is asserted
	er$inr	==	256.+21.	; invalid number of retries
	er$npn	==	256.+22.	; no previous number dialed
	er$mdm	==	256.+23.	; please set modem first
	er$ndf	==	256.+24.	; no dial formatting string
	er$idl	==	256.+25.	; can't release modem
	er$unm	==	256.+26.	; unknown modem type
	er$nnf	==	256.+27.	; no number found for name
	er$abk	==	256.+28.	; aborted from keyboard
	er$wke	==	256.+29.	; can't get wake string from modem
	er$oct	==	256.+30.	; must be octal 1 to 36 only
	er$iln	==	256.+31.	; illegal logical name
	er$wks	==	256.+32.	; wake string is undefined
	er$pls	==	256.+33.	; please SET LINE first
	er$lwe	==	256.+34.	; logfile write error
	er$amb	==	256.+35.	; ambiguous command
	er$not	==	256.+36.	; not a local Kermit..
	er$ram	==	256.+37.	; ambiguous REMOTE command
	er$run	==	256.+38.	; unrecognizable REMOTE command
	er$ttx	==	256.+39.	; /63/ TT not supported here
	er$unr	==	256.+40.	; unrecognizable command
	er$snd	==	256.+41.	; send syntax error
	er$uns	==	256.+42.	; /E64/ unsupported command
	er$amo	==	256.+43.	; /E64/ Ambiguous option or value

	maxerr	=	43.		; must be abs(maxerr)


	.sbttl	Error messages mapped

errmap:	.word	baderr		; come here when error doesn't map
	.word	      10$, 20$, 30$, 40$, 50$, 60$, 70$, 80$, 90$
	.word	100$,110$,120$,130$,140$,150$,160$,170$,180$,190$
	.word	200$,210$,220$,230$,240$,250$,260$,270$,280$,290$
	.word	300$,310$,320$,330$,340$,350$,360$,370$,380$,390$
	.word	400$,410$,420$,430$


10$:	.asciz	"Please open a LOGFILE first"
20$:	.asciz	"Can't log RAW I/O with another disk_based DEBUG option set"
30$:	.asciz	"Can't do this with RAW I/O logging on"
40$:	.asciz	"Insufficient free memory remaining"
50$:	.asciz	"Unknown speed"
60$:	.asciz	"Maximum of 31 entries in the BINARY_TYPE list"
70$:	.asciz	"Illegal file type string"
80$:	.asciz	"Retries must be between 3 and 30"
90$:	.asciz	"Time_out must be between 0 and 94"	; /62/
100$:	.asciz	"Minimum packet length is 20"		; /62/
110$:	.asciz	"Bad option or value"
120$:	.asciz	"Ambiguous SET command"
130$:	.asciz	"Unrecognizable SET command"
140$:	.asciz	"Can't connect TT to TT"
150$:	.asciz	"Syntax is ASS dev DK, only DK is supported"
160$:	.asciz	"Syntax is GET file.typ [dev:][asfile.new]"
170$:	.asciz	"Ambiguous topic"
180$:	.asciz	"Unrecognizable topic"
190$:	.asciz	"Server sub-commands are not supported"
200$:	.asciz	"Can't DIAL whilst DCD is asserted, use HANGUP first"
210$:	.asciz	"Invalid number of retries"
220$:	.asciz	"No previous number dialed"
230$:	.asciz	"Please SET MODEM first"
240$:	.asciz	"FORMAT string undefined"
250$:	.asciz	"Modem not restored to its idle state"
260$:	.asciz	"Unknown modem type"
270$:	.asciz	"No number found for specified name"
280$:	.asciz	"Aborted from keyboard"
290$:	.asciz	"Can't get wake$prompt from modem"
300$:	.asciz	"Range is 1 to 36 octal"
310$:	.asciz	"Illegal logical name"
320$:	.asciz	"WAKE_STRING undefined"
330$:	.asciz	"Please SET LINE first"
340$:	.asciz	"Logfile write error"
350$:	.asciz	"Ambiguous command"
360$:	.asciz	"Not running as a LOCAL Kermit"
370$:	.asciz	"Ambiguous REMOTE command"
380$:	.asciz	"Unrecognizable REMOTE command"
390$:	.asciz	"TT is not supported here"	; /63/
400$:	.asciz	"Unrecognizable command"
410$:	.asciz	"Syntax is SEND file.typ [dev:][asfile.new]"
420$:	.asciz	"Unsupported command"		; /E64/
430$:	.asciz	"Ambiguous option or value"	; /E64/
baderr:	.asciz	"Unknown error"
	.even

	.psect	$code
	.sbttl	Error message generator	; /E64/ somewhat changed..

;	F I P E R R
;
;	input:	  (r5)	= error number
;	output:	 2(r5)	= buffer for error message text

fiperr::save	<r0,r1,r2>
	mov	4(r5)	,r2		; r2 := addr( errtxt )
	mov	@2(r5)	,r0
	bgt	5$
	neg	r0
5$:	cmp	r0,#256.		; greater than 256?
	bhis	6$			; yes, internal error
	movb	r0	,@#FIRQB+fqerno	; movbe the error number .
	movb	#errfq	,@#FIRQB+FQFUN	; set up for sys err call
	CALFIP
	mov	#28.	,r0		; error text length
	mov	#FIRQB+fqerno	,r1	; r1 := addr( actual msg )
	br	10$			; copy error message to buffer
6$:	sub	#256.,r0		; get it in range
	cmp	r0	,#maxerr	; is this a valid call today?
	blos	7$			; yes
	clr	r0			; badness
7$:	asl	r0			; ya, get error number into word
	mov	errmap(r0),r1		; offset and get the text address
	mov	#erbfsiz,r0		; set maximum msg size
10$:	movb	(r1)+	,(r2)+		; go and transfer the text
	beq	20$			; did we find the end yet
	sob	r0	,10$		; all thirty bytes worth.
20$:	clrb	@r2
40$:	unsave	<r2,r1,r0>
	return				; all done


	.end